16x2 LCD with I2C, on Arduino

The 16x2 character LCD is the most reused part in student electronics. It is on the water-level controller, the weighing scale, the attendance system and the greenhouse monitor, because a project that shows its reading on a screen demonstrates itself and a project that only prints to a laptop does not.

Wired directly it needs twelve connections and a contrast potentiometer. With an I2C backpack it needs four. Buy the version with the backpack already soldered on.

What the backpack does

The small board on the back of the display carries a PCF8574, an I2C port expander. Instead of the Arduino wiggling eight data lines and three control lines itself, it sends bytes down two wires and the expander does the wiggling.

Wiring

Step one: find the address

This is the single reason most I2C displays appear dead. Modules ship at one of two addresses, 0x27 or 0x3F, and every tutorial sketch hard-codes one of them. If yours is the other one, you get a lit backlight and a blank screen — which looks exactly like a broken display.

Run this first, every time, on any new module.

#include <Wire.h>

void setup() {
  Wire.begin();
  Serial.begin(9600);
  while (!Serial) { }        // needed on a Leonardo or Micro, harmless elsewhere
  Serial.println("Scanning the I2C bus...");

  int found = 0;
  for (byte address = 1; address < 127; address++) {
    Wire.beginTransmission(address);
    // A device that is present acknowledges. endTransmission returns 0 for
    // an ACK and non-zero for silence.
    if (Wire.endTransmission() == 0) {
      Serial.print("  device at 0x");
      if (address < 16) Serial.print("0");
      Serial.println(address, HEX);
      found++;
    }
  }

  if (found == 0) {
    Serial.println("Nothing on the bus - check SDA, SCL, 5V and GND");
  }
}

void loop() { }

Whatever it reports goes into the next sketch. If it finds nothing at all, the fault is in the four wires or the power — not in the display and not in your code.

Step two: the contrast trimmer

There is a small blue potentiometer on the backpack. It sets the contrast, it ships in a random position, and at the wrong end of its travel the screen shows either nothing at all or a row of solid white blocks. Both are routinely mistaken for a dead module.

1. 1

   Power the board with any sketch running

   The backlight should be on. If it is not, check VCC and GND first.

2. 2

   Turn the trimmer slowly, all the way, with a small screwdriver

   Somewhere in that travel the characters appear. If you only ever see blocks or only ever see blank, you have not been to both ends.

3. 3

   Stop where the text is crisp and the background is clean

   A little past the point where blocks fade out is usually right.

The library, and the sketch

Install LiquidCrystal_I2C through the Library Manager. There are several forks of it with slightly different function names — the one by Frank de Brabander is the one nearly every example targets, and lcd.init() rather than lcd.begin() is how you can tell you have it.

• OpenLiquidCrystal_I2C — Frank de BrabanderInstall through Sketch → Include Library → Manage Libraries rather than a zip, so it stays current and matches your IDE.

#include <Wire.h>
#include <LiquidCrystal_I2C.h>

// Address from the scanner. 0x27 and 0x3F are the two common ones.
LiquidCrystal_I2C lcd(0x27, 16, 2);

void setup() {
  lcd.init();
  lcd.backlight();

  lcd.setCursor(0, 0);          // column, then row - both count from 0
  lcd.print("projectkit.in");
  lcd.setCursor(0, 1);
  lcd.print("Temp:");
}

void loop() {
  float celsius = 27.4;         // whatever your sensor returned

  // Only redraw the part that changes. Clearing the whole screen every pass
  // is what makes an LCD flicker.
  lcd.setCursor(6, 1);
  lcd.print(celsius, 1);
  lcd.print((char)223);         // the degree symbol in this character set
  lcd.print("C  ");             // trailing spaces wipe the old, longer value

  delay(500);
}

Printing values without leaving debris

This is the bug that makes a working project look unfinished, and it is in a great many student demonstrations.

An LCD does not erase. Printing 100 and then 99 over it leaves `990` — the old third character is still there, because nothing told it to go. Your distance sensor reads a plausible number that is silently wrong by a digit.

• Pad with trailing spaces. lcd.print("99 ") wipes what the longer value left. Simplest and what the sketch above does.
• Never use `lcd.clear()` in a fast loop. It works, and it makes the screen flicker visibly because the whole display goes blank between frames.
• Redraw only what changes. Print the fixed labels once in setup() and update just the numbers, with setCursor putting you back at the same column each time.

When it does not work

Where to take it

• Add a DHT and it is a room monitor that needs no computer.
• Add an RTC on the same two wires and it is a clock with a temperature readout — no extra pins.
• Add a 4x4 keypad and it is a password-entry panel, which is most of a door-lock project.
• Learn createChar and you can draw a battery gauge or a level bar out of custom characters, which reads far better in a demonstration than a bare number.